aUCBLogo Demos and Tests / autoloadtest

to autoloadTest
;This program is designed to run in autoload mode.
;You can activate autoload mode from the Run menu,
;with the command "Autoload file to Workspace".
;Press F9 to start it once,
;then edit the subprocedures of zzz_main,
;while the autoloadTest program is running.
;You can stop the program by a key press in the Console.

;And the most important thing: Have fun!!!

   setUpdateGraph "false
   a=0
   forever
    [   clearScreen
      ;pr repcount
      catch "error [ignore runResult [zzz_main]]
      err=Error
      if :err != []
      [   clearText
         print :err.2
         waitMS 200
      ]
      updategraph
      updateVars
      dispatchMessages
      waitMS 100
      if Key? [stop]
   ]
end

to zzz_main
;Use alphabetically high names for superprocedures,
;because in the autoload mode procs are parsed sorted by name!
;Now start the program with F9,
;and try to modify it while it is running!

   box
   ;disls box fd 20 fill enls
   star

   ;p1      ;some procedures to start with.
   ;p2      ;Uncomment them to see the results!
   ;p3
   ;hideTurtle p4 300 a=:a+1 showTurtle
   ;rtest
end

to p1
   hideTurtle
   a=1   ;comment this line if you want to see an animation!
   a=mod :a+0.0000002 2
   repeat 2000
   [   fd repcount/100
      rt (2*repcount)^1.1*:a
   ]
   showTurtle
end

to p2
   box
end

to p3
   star
end

to p4 :n
   if :n > 1 [p4 :n/1.01]
   fd :n
   right :a
end

to rtest
   perspective
   cs
   down 90
   rt 0
   rr 40
   fillRect [-200 -100][300 100]
end